@ECHO OFF
CHCP 65001 >NUL
REM **************************************************
REM Dieser command sichert die Inhalt von bfds in windows
REM auf der OFFSITE platte (Veracrypt Partition) mittels
REM SMB Freigaben von bfds und xcopy.
REM **************************************************
SETLOCAL


REM **************************************************
REM Einbinden der Veracrypt Partition
REM **************************************************
echo Festplatte NASOFFSITE1 wird entschlüsselt und eingebunden
SET VOLUME_LABEL=NASOFFSITE1
SET VERACRYPT_PATH="C:\Program Files\VeraCrypt\VeraCrypt.exe"
SET VOLUME_MOUNT_PATH="B:\"
SET VOLUME_PASSWORD=123456
REM get the Password for the volume from the user
SET /P VOLUME_PASSWORD=Bitte geben Sie das Passwort für die Festplatte %VOLUME_LABEL% ein:
%VERACRYPT_PATH% /q /v "\Device\Harddisk2\Partition1" /l B /p "%VOLUME_PASSWORD%"

SET SOURCE=\\bfds
SET DESTINATION="B:\\"

echo Festplatte NASOFFSITE1 wird gesucht
IF NOT EXIST %DESTINATION% (
    echo Festplatte NASOFFSITE1 nicht gefunden, bitte in Veracrypt als Laufwerk B:\ einbinden!
    PAUSE
    exit /B
)

CALL :RunRobocopy "ebooks"
CALL :RunRobocopy "movies"
CALL :RunRobocopy "music"
CALL :RunRobocopy "peggy"
CALL :RunRobocopy "rob"
exit /B  %ERRORLEVEL%

REM **************************************************
REM Funktion zum Ausführen von robocopy
:RunRobocopy
    SET COPYPATH=%~1
    IF NOT EXIST %SOURCE%\%COPYPATH% (
        echo Quelle nicht gefunden! Bitte öffne die SMB Freigbe: %SOURCE%\%COPYPATH%
        PAUSE
        exit /B  %ERRORLEVEL%
    )
    SET SCRIPT_PATH=%~dp0
    SET TODAY=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
    SET LOGFILE="%SCRIPT_PATH%robocopy_log_%COPYPATH%_%TODAY%.txt"
    echo LOGFILE: %LOGFILE%
    robocopy %SOURCE%\%COPYPATH% %DESTINATION%\%COPYPATH% /E /mt /z /J /COPY:DAT /R:3 /W:5 /LOG+:%LOGFILE% /TEE
    REM Erklärung der Parameter:
    REM /E: Kopiert Unterverzeichnisse inklusive leerer Verzeichnisse
    REM /mt: Multithreaded copying
    REM /z: Kopiert Dateien im Restart-Modus (d.h. kopiert Dateien, die bereits existieren)
    REM /COPY:DAT: Kopiert Dateiattribute, Zeitstempel und Sicherheitsinformationen
    REM /R:3: Anzahl der Wiederholungsversuche bei Fehlern
    REM /W:5: Wartezeit zwischen den Wiederholungsversuchen
    REM /J: Kopiert mit unbuffered I/O (empfohlen für große Dateien)
    REM /LOG+: Protokolliert den Kopiervorgang in eine Datei
    REM /TEE: Protokolliert den Kopiervorgang auch in der Konsole
GOTO :EOF
REM **************************************************

REM **************************************************
REM Partiton wieder aushängen
REM **************************************************
%VERACRYPT_PATH% /d B /q